Alt 16 Kasım 2023, 02:42   #1
Standart Socket Proxy ve Remote proxy koruması

HTML-Kodu:
alias _proxybot return ProxyServ
alias _oper return Bot opersifre
alias _pass return nicksifre
alias _supass return supassifre
alias _username return Proxy Sys v1.0.2
alias _sunucu return irc.sunucuadi.com
alias _sunucuip return 1.2.3.4
alias _port return 6667
alias _bots return #bot
alias _kontrol return #services
alias _xline return #Xline


alias _saatkontrol {
  if $regex($token($time,1-2,58),/^00:00$/Si) && !$hget(Saat,Kontrol) {
    _cezaoper
    .hinc -msu180 Saat Kontrol
  }
  else {
    $iif(!$sock(proxybot),sockopen proxybot $_sunucu $_port)
  }
}

alias swproxybot $iif($sock(proxybot).status == active,sockwrite -nt proxybot $1-)

on *:sockclose:proxybot:$+(.timer,proxybot) 1 2 sockopen proxybot $_sunucuip $_port
on *:sockopen:proxybot:{
  if ($sockerr) { sockclose proxybot | $+(.timer,proxybot) 1 2 sockopen proxybot $_sunucuip $_port | returnex }
  swproxybot NICK $+($_proxybot,$r(10,9999)) 
  swproxybot USER $_ident "" " $+ $iif($host,$host,$ip) $_username
  sockmark $sockname $_proxybot
}
on *:sockread:proxybot:{
  if ($sockerr) { sockclose proxybot | $+(.timer,proxybot) 1 2 sockopen proxybot $_sunucuip $_port | returnex }
  var %;proxybot | sockread %;proxybot | tokenize 32 %;proxybot
  if ($1 = ping) swproxybot pong $remove($2,:) 
  elseif $regex($2,/(001|433)/) { swproxybot oper $_oper | swproxybot ns ghost $_proxybot $_pass | swproxybot ns release $_proxybot $_pass | swproxybot join #0,0 | $+(.timer,$rand(100,999)) 1 3 swproxybot nick $_proxybot }
  elseif $1 == error && $2 == :closing { sockclose proxybot | $+(.timer,proxybot) 1 2 sockopen proxybot $_sunucuip $_port }  
  elseif $regex($2,/(473|475|471|474)/) { swproxybot sajoin $_proxybot $4 }
  elseif $regex($2,/(481|411)/) { swproxybot oper $_oper | swproxybot nick $_proxybot | swproxybot nickserv identify $_pass }
  elseif ($2 == NICK) { 
    if $_nick($1) == $_proxybot { swproxybot ns ghost $_proxybot $_pass | swproxybot ns release $_proxybot $_pass | $+(.timer,$rand(100,999)) 1 3 swproxybot nick $_proxybot }
    elseif $right($3,-1) == $_proxybot {
      swproxybot nickserv identify $_pass      
      swproxybot oper $_oper
      $iif($_supass,swproxybot os su $_supass)
      swproxybot join 0,0
      swproxybot mode $right($3,-1) +qHp-h
      swproxybot chghost $right($3,-1) $_host
      $+(.timer,_proxybotgir) 1 5 swproxybot sajoin $right($3,-1) $+($_kontrol,$chr(44),$_bots,$chr(44),$_log,$chr(44),$_xline)
    }
  }
  elseif $regex($2,/366/) && !$istok($_kontrol $_bots $_log $_xline,$4,32) { swproxybot part $4 }  
  elseif $regex($2,/^PART$/i) {
    if $regex($_nick($1),/^ $+ $_proxybot $+ $/Si) && $istok($_kontrol $_bots $_log $_xline,$3,32) { swproxybot sajoin $_nick($1) $3 }
  }
  elseif $regex($2,/^KICK$/i) {
    if $regex($4,/^ $+ $_proxybot $+ $/Si) && $istok($_kontrol $_bots $_log $_xline,$3,32) { swproxybot sajoin $4 $3 }
  }
  elseif $regex($2,/^JOIN$/i) {
    if $regex($_nick($1),/ $+ $+(^,$_proxybot,$) $+ /Si) {
      if $istok($_kontrol $_bots $_log $_xline,$right($3,-1),32) {
        swproxybot mode $right($3,-1) -qao+h $str($+($_nick($1),$chr(32)),5)
        swproxybot mode $_nick($1) +qHp-h
        swproxybot chghost $_nick($1) $_host
      }
    }
  }
  elseif $regex($2,/^MODE$/Si) && $regex($3,/^#/) {
    if $regex($4,^\+(\S+)?(b)(\S+)?) && $5 {
      swproxybot mode $3 -b *!*@*
      if $regex($5-,/ $+ $_proxybot $+ /i) { swproxybot mode $3 -b $_proxybot }
    }
    elseif $regex($4,^\-(\S+)?(h)(\S+)?) || $regex($4,^\+(\S+)?(a|q|o)(\S+)?) && $regex($5-,/ $+ $_proxybot $+ /i) { swproxybot mode $3 -qao+h $str($+($_proxybot,$chr(32)),5) }
  }
  elseif $regex($2,/^NOTICE$/Si) && $regex($4-,/Client connecting on port/Si) {
    var %:nick $token($token($4-,1,40),-1,32), %:ident $token($token($4-,1,64),2,40), %:ip $token($token($4-,2,64),1,41), %:port $token($token($4-,1,58),-1,32)
    if $istok($_sunucuip %:myip,%:ip,32) { return }
    if $hget(MuafPort,%:port) || $hget(MuafNick,%:nick) || $hget(MuafIP,%:ip) { return }
    swproxybot who +I %:nick
    swproxybot notice %:nick :Güvenlik (SOCKS, HTTP, TOR, PROXY) taramasından geçiyorsunuz.
    swproxybot notice %:nick :Bu sistem kötü niyetli baglantilari yasaklamak amaci ile gelistirilmis bir Koruma sistemi'dir.
  }
  elseif $regex($2,/352/) {
    var %:wnick $8, %:wip $6
    if $istok($_sunucuip %:myip,%:wip,32) { return }
    if $hget(MuafNick,%:wnick) || $hget(MuafIP,%:wip) { return }
    if (%:proxy == on) {
      if $hget(Proxy,%:wip) || $hget(Proxy1,%:wip) { 
        swproxybot gline $+(*@,%:wip) +5h Proxy Yasak.. [HASH] 
        swproxybot privmsg $_xline :(4PROXY GİRİŞ) %:wip numarali IP proxy'dir. -HASH- (Nick: %:wnick $+ ) 
        return 
      }
    }
    var %:rnd $r(1000,99999) 
    sockopen $+(proxybotkor,%:rnd,%:wnick) goktugservis.net 80 
    sockmark $+(proxybotkor,%:rnd,%:wnick) $+(%:wip,¿,%:wnick)
  }
}

on *:sockopen:proxybotkor*:{ 
  var %:pkoruma sockwrite -nt $sockname
  %:pkoruma GET $+(/?ip=,$token($sock($sockname).mark,1,191))  HTTP/1.1 
  %:pkoruma Host: $sock($sockname).addr
  %:pkoruma Accept: image/jpeg, application/x-ms-application, image/gif, application/xaml+xml, image/pjpeg, application/x-ms-xbap, */*
  %:pkoruma Accept-Language: tr-TR
  %:pkoruma User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
  %:pkoruma Connection: Keep-Alive
  %:pkoruma $crlf
}
on *:sockread:proxybotkor*:{ 
  if ($sockerr) { .sockclose $sockname | return }
  var %:pkr | sockread -f %:pkr | tokenize 32 %:pkr
  if $regex($1-,/numaral[ıiİ] [Iİi]P proxy\'dir/i) {
    if (%:proxy == on) {  
      swproxybot gline $+(*@,$token($sock($sockname).mark,1,191)) +5h Proxy Yasak.. $+([,$token($1-,2,45),])
      swproxybot privmsg $_xline (4PROXY GİRİŞ) $token($sock($sockname).mark,1,191) numarali IP proxy'dir. $+(-,$token($1-,2,45),-) (Nick: $token($sock($sockname).mark,2,191) $+ ) 
      sockclose $sockname
      return
    }
  }
  if $regex($1-,/numaral[ıiİ] [Iİi]P proxy de[qgğĞ][ıiİ]ld[ıiİ]r/i) {
    var %:t_ip $token($sock($sockname).mark,1,191), %:t_nick $token($sock($sockname).mark,2,191)
    $+(.timer,%:t_nick,¿join) 1 3 _dagit %:t_nick %:t_ip
    swproxybot privmsg $_xline (3GİRİŞ) $token($sock($sockname).mark,1,191) numarali IP proxy degildir. (Nick: $token($sock($sockname).mark,2,191) $+ ) 
    sockclose $sockname
    return
  }
}
Remote Kodu


Kod:
menu * {
  Proxy Koruması
  .Aç:/.enable #ProxyKoruma | echo -a Proxy koruması açıldı..
  .Kapat:/.disable #ProxyKoruma | echo -a Proxy koruması kapatıldı..
  .-
  .Log Kanalı:.set %proxylogkanali $$?="Örnek #kanal1,#kanal2" 
}

#ProxyKoruma off
on *:snotice:*Client connecting*:{
  ; alt satır kopyalanarak muaf port eklenebilir
  if $remove($8,1,33,:) == 7000 { halt }
  .who +I $token($token($4-,2,58),1,32)
}

raw 352:*:{
  var %:r $+($left($md5($ticks),$r(5,20)),$6)
  sockopen $+(proxy,%:r) goktugservis.net 80 
  sockmark $+(proxy,%:r) $+($4,¿,$6)
}

on *:sockopen:proxy*:{ 
  sockwrite -nt $sockname GET $+(/dnsbl/?ip=,$token($sock($sockname).mark,1,191))  HTTP/1.1 
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Accept: image/jpeg, application/x-ms-application, image/gif, application/xaml+xml, image/pjpeg, application/x-ms-xbap, */*
  sockwrite -nt $sockname Accept-Language: tr-TR
  sockwrite -nt $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
  sockwrite -nt $sockname Connection: Keep-Alive
  sockwrite -nt $sockname $crlf
}

on *:sockread:proxy*:{
  if ($sockerr) { .sockclose $sockname | return }
  var %:proxy | sockread -f %:proxy | tokenize 32 %:proxy
  ;msg %proxylogkanali -a %:proxy
  if $regex($1-,/sonuc red/i) {
    gzline $+(*@,$token($sock($sockname).mark,1,191)) +5h Proxy Yasak!
    /msg %proxylogkanali (4GİRİŞ) $token($sock($sockname).mark,1,191) numaralı IP Proxy'dir. (Nick: $token($sock($sockname).mark,2,191) $+ )
    sockclose $sockname
    return
  }
  if $regex($1-,/sonuc green/i) {
    /msg %proxylogkanali (3GİRİŞ) $token($sock($sockname).mark,1,191) numaralı IP Proxy degildir. (Nick: $token($sock($sockname).mark,2,191) $+ )
    sockclose $sockname
    return
  }
  if $regex($1-,/sonuc orange/i) {
    /msg %proxylogkanali (7GİRİŞ) $token($sock($sockname).mark,1,191) numaralı IP sorgulanamadı! (Nick: $token($sock($sockname).mark,2,191) $+ )
    sockclose $sockname
    return
  }
}
#ProxyKoruma end



Daemon isimli Üye şimdilik offline konumundadır  
Alıntı ile Cevapla
Alt 16 Kasım 2023, 02:43   #2
Standart Cevap: Socket Proxy ve Remote proxy koruması

Ziyaretçilere içerik gizlenmiştir.

İçerikleri görebilmek için üye olmalı ve üye girişi yapmalısınız.
Giriş Yap Kayıt Ol




Sende [Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
birsevda isimli Üye şimdilik offline konumundadır  
Alıntı ile Cevapla
Alt 16 Kasım 2023, 02:49   #3
Standart Cevap: Socket Proxy ve Remote proxy koruması

Ziyaretçilere içerik gizlenmiştir.

İçerikleri görebilmek için üye olmalı ve üye girişi yapmalısınız.
Giriş Yap Kayıt Ol




UçuRumu SevenLeRin KanatLaRı oLmaLı...

Tujh Mein Rab Dikhta Hai













KıRıK isimli Üye şuanda  online konumundadır  
Alıntı ile Cevapla
Alt 19 Kasım 2023, 15:19   #4
Standart Cevap: Socket Proxy ve Remote proxy koruması

Ziyaretçilere içerik gizlenmiştir.

İçerikleri görebilmek için üye olmalı ve üye girişi yapmalısınız.
Giriş Yap Kayıt Ol

Sado isimli Üye şimdilik offline konumundadır  
Alıntı ile Cevapla
Cevapla

Yer İmleri

Etiketler
koruması, proxy, remote, socket


Şu anda bu konuyu görüntüleyen etkin kullanıcılar: 1 (0 üye ve 1 ziyaretçi)
 
Seçenekler
Stil

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB kodu Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Kapalı
Pingbacks are Kapalı
Refbacks are Kapalı



Bilgilendirme

Sitemiz bir genel forum sitesidir. Bu yüzden sitemize kaydolan herkes, kontrol edilmeksizin mesaj/konu/resim paylaşabilmektedir. Bu sebepten ötürü, sitemiz üzerinden paylaşılan mesajlar, konular ve resimlerden doğabilecek olan yasal sorumluluklar paylaşan kullanıcıya aittir. Forumkolik, hiçbir yasal sorumluluk kabul etmemektedir. Illegal herhangi bir faaliyet görülmesi durumunda İLETİŞİM sayfasından bildirim yapıldığı takdirde, mesaj, konu ya da resim en fazla 24 saat içerisinde silinecektir.

Forum Bilgileri

Forum Sahibi: KIRIK

Forum Manager: SaRe

Graphic Designer: Müptela

İ[email protected]

Powered by vBulletin® Version 3.8.12 -
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Tüm Zamanlar GMT +4 Olarak Ayarlanmış. Şuanki Zaman: 22:37.

FORUMKOLIK.NET ® © JRodix.Com Sunucularında Barınmaktadır.

Evden Eve Nakliyat Çekici Mobil Sohbet Evden Eve Nakliyat Yalın Üretim